Next: Texture of land data: Up: TEXTURE Previous: TEXTURE

## Texture of horizontal bedding, marine data

Randomness is introduced into the earth with a random function of midpoint y and depth z. This randomness is impressed on some geological ``layer cake'' function of depth z. This is done in the first half of subroutine synmarine() .
```
subroutine synmarine ( data, nt,nh,ny, nz)
integer                      nt,nh,ny, nz,    it,ih,iy,is,iz, ns, iseed
real         data( nt,nh,ny),       layer, rand01
temporary real                          refl(nz,ny), depth(nz)
iseed= 1992;    ns = ny
do iz= 1, nz {                                  # 0 < rand01() < 1
depth( iz) =  nt * rand01(iseed)        # Reflector depth
layer      =  2. * rand01(iseed) - 1.   # Reflector strength
do iy= 1, ny {                          # Impose texture on layer
refl(iz,iy) = layer * (1. + rand01(iseed))
}
}
call null(             data, nt*nh*ny)          # erase data space
do is= 1, ns    {                               # shots
do ih= 1, nh    {                               # down cable h = (g-s)/2
do iz= 1, nz    {                               # Add hyperbola for each layer
iy = (ns-is)+(ih-1)                     # y = midpoint
iy = 1 + (iy-ny*(iy/ny))                # periodic with midpoint
it = 1 + sqrt( depth(iz)**2 + 25.*(ih-1)**2 )
if( it <= nt)
data(it,ih,is) = data(it,ih,is) + refl(iz,iy)
}}}
return; end
```

The second half of subroutine synmarine() scans all shot and geophone locations and depths and finds the midpoint, and the reflection coefficient for that midpoint, and adds it into the data at the proper travel time.

There are two confusing aspects of subroutine synmarine() . First, refer to figure 1 and notice that since the ship drags the long cable containing the receivers, the ship must be moving to the left, so data is recorded for sequentially decreasing values of s. Second, to make a continuous movie from a small number of frames, it is necessary only to make the midpoint axis periodic, i.e. when a value of iy is computed beyond the end of the axis ny, then it must be moved back an integer multiple of ny.

What does the final data space look like? This question has little meaning until we decide how the three-dimensional data volume will be presented to the eye. Let us view the data much as it is recorded in the field. For each shot point we see a frame in which the vertical axis is the travel time and the horizontal axis is the distance from the ship down the towed hydrophone cable. The next shot point gives us another frame. Repetition gives us the accompanying program that produces a cube of data, hence a movie. This cube is synthetic data for the ideal marine environment. And what does the movie show?

 synmarine Figure 7 Output from synmarine() subroutine (with temporal filtering on the t-axis).

A single frame shows hyperbolas with imposed texture. The movie shows the texture moving along each hyperbola to increasing offsets. (I find that no sequence of still pictures can give the impression that the movie gives). Really the ship is moving; the texture of the earth is remaining stationary under it. This is truly what most marine data looks like, and the computer program simulates it. Comparing the simulated data to real marine-data movies, I am impressed by the large amount of random lateral variation required in the simulated data to achieve resemblance to field data. The randomness seems too great to represent lithologic variation. Apparently it is the result of something not modeled. Perhaps it results from our incomplete understanding of the mechanism of reflection from the quasi-random earth. Or perhaps it is an effect of the partial focusing of waves sometime after they reflect from minor topographic irregularities. A full explanation awaits more research.

 shotmovie Figure 8 Press button for field data movie.

Next: Texture of land data: Up: TEXTURE Previous: TEXTURE
Stanford Exploration Project
12/26/2000